# Maintainer: Cedric Girard <girard.cedric@gmail.com>
pkgname=xmobar-git
pkgver=20120905
pkgrel=1
pkgdesc="A minimal status bar for the XMonad Window Manager"
arch=('i686' 'x86_64')
url="http://projects.haskell.org/xmobar/"
license=('custom:BSD3')
makedepends=(
    'ghc'
    'haskell-x11<1.7'
    'haskell-x11-xft<0.4'
    'haskell-alsa-core<0.6'
    'haskell-alsa-mixer<0.2'
    'haskell-bytestring=0.9.2.1'
    'haskell-containers=0.4.2.1'
    'haskell-dbus>=0.10'
    'haskell-directory=1.1.0.2'
    'haskell-filepath=1.3.0.0'
    'haskell-hinotify<0.4'
    'haskell-libmpd<0.9'
    'haskell-mtl<2.2'
    'haskell-old-locale=1.0.0.4'
    'haskell-parsec<3.2'
    'haskell-process=1.1.0.1'
    'haskell-stm<2.5'
    'haskell-time=1.4'
    'haskell-timezone-olson<0.2'
    'haskell-timezone-series<0.2'
    'haskell-unix=2.5.1.1'
    'haskell-utf8-string<0.4'
    'libxrandr'
    'wireless_tools'
    'git'
)
depends=('wireless_tools' 'gmp' 'libxml2' 'libxrandr' 'libxinerama' 'libxft' 'alsa-lib')
conflicts=('xmobar' 'xmobar-darcs')
install=
source=()
md5sums=()

_gitroot="https://github.com/jaor/xmobar.git"
_gitname="xmobar"

build() {
    cd "${srcdir}"
    msg "Connecting to GIT server...."

    if [ -d $_gitname ] ; then
        cd $_gitname && git pull origin
        msg "The local files are updated."
    else
        git clone $_gitroot $_gitname
    fi

    msg "GIT checkout done or server timeout"
    msg "Starting make..."

    rm -rf "${srcdir}/$_gitname-build"
    git clone "${srcdir}/$_gitname" "${srcdir}/$_gitname-build"
    cd "${srcdir}/$_gitname-build"

    runhaskell Setup configure --flags="all_extensions" --prefix=/usr
    runhaskell Setup build

    install -D -m644 license ${pkgdir}/usr/share/licenses/$pkgname/BSD3
}

package() {
    cd "${srcdir}/$_gitname-build"
    runhaskell Setup copy --destdir=${pkgdir}
}