Add 'autojump-git/' from commit 'f34af1494901e1452ea703653403388878e97e01'

git-subtree-dir: autojump-git
git-subtree-mainline: 8f759a8896
git-subtree-split: f34af14949

autojump-git/.SRCINFO

@@ -0,0 +1,18 @@
+# Generated by mksrcinfo v8
+# Wed May 18 09:02:52 UTC 2016
+pkgbase = autojump-git
+	pkgdesc = A faster way to navigate your filesystem from the command line
+	pkgver = 22.3.0.r14.g9a6e286
+	pkgrel = 1
+	url = http://github.com/joelthelion/autojump
+	arch = any
+	license = GPL3
+	makedepends = git
+	depends = python
+	provides = autojump
+	conflicts = autojump
+	source = git+https://github.com/joelthelion/autojump.git
+	md5sums = SKIP
+
+pkgname = autojump-git
+

autojump-git/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Cedric Girard <girard.cedric@gmail.com>
+# Contributor: Jason Axelson <jason.axelsonATgmail.com>
+# Contributor: Sean Escriva <sean.escrivaATgmail.com>
+# Contributor: William Ting <william.h.tingATgmail.com>
+
+pkgname=autojump-git
+pkgver=22.3.0.r14.g9a6e286
+pkgrel=1
+pkgdesc="A faster way to navigate your filesystem from the command line"
+arch=(any)
+url="http://github.com/joelthelion/autojump"
+license=('GPL3')
+depends=('python')
+makedepends=('git')
+conflicts=('autojump')
+provides=('autojump')
+replaces=()
+backup=()
+source=('git+https://github.com/joelthelion/autojump.git')
+md5sums=('SKIP')
+
+_gitname="autojump"
+
+pkgver() {
+    cd ${_gitname}
+    git describe --long --tags | sed 's/^release\-v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+    cd ${_gitname}
+    sed -i 's$#!/usr/bin/env python$#!/usr/bin/env python3$' bin/autojump bin/*.py
+}
+
+package() {
+    cd ${_gitname}
+    ./install.py --prefix 'usr/' --destdir "${pkgdir}" --zshshare 'usr/share/zsh/site-functions'
+
+    cd "${pkgdir}"/usr/share/$_gitname
+    for i in $_gitname.* ; do
+        ln -s /usr/share/$_gitname/$i \
+            "${pkgdir}"/etc/profile.d/$i
+    done
+
+    #https://github.com/joelthelion/autojump/pull/339
+    sed -i "s!/usr/local/!/usr/!g" "${pkgdir}"/etc/profile.d/$_gitname.sh
+    #FS#43762
+    sed -i '27,31d' "${pkgdir}"/etc/profile.d/$_gitname.sh
+}
+
+
+# vim:set ts=4 sw=4 et: