upgpkg: woob-git 3.6.r333.gecb44eab4-1

adopted and fixed

woob-git/.SRCINFO

@@ -0,0 +1,35 @@
+pkgbase = woob-git
+	pkgdesc = Core library and modules for Web Outside of Browsers
+	pkgver = 3.6.r333.gecb44eab4
+	pkgrel = 1
+	url = https://woob.tech
+	arch = any
+	license = LGPL3
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	makedepends = python-setuptools
+	makedepends = git
+	depends = python-lxml
+	depends = python-cssselect
+	depends = python-requests
+	depends = python-dateutil
+	depends = python-yaml
+	depends = python-html2text
+	depends = python-six
+	depends = python-unidecode
+	depends = python-pillow
+	depends = python-babel
+	depends = python-simplejson
+	optdepends = python-prettytable: CLI output formatting
+	optdepends = python-feedparser: required by some modules
+	provides = woob-headless
+	conflicts = weboob-headless
+	conflicts = weboob-git
+	conflicts = weboob-qt
+	replaces = woob-headless
+	replaces = weboob
+	source = woob::git+https://gitlab.com/woob/woob.git
+	sha256sums = SKIP
+
+pkgname = woob-git

woob-git/.gitignore

@@ -0,0 +1,14 @@
+*.tar
+*.tar.*
+*.jar
+*.exe
+*.msi
+*.zip
+*.tgz
+*.log
+*.log.*
+*.sig
+
+pkg/
+src/
+woob/

woob-git/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Cedric Girard <cgirard [dot] archlinux [at] valinor [dot] fr>
+# Contributor: Benjamin Vialle <archlinux@vialle.io>
+# Contributor:  Dimitris Kiziridis <ragouel at outlook dot com>
+# Contributor: sputnick <gilles *DOT* quenot *AT* gmail *DOT* com>
+# Contributor: ianux <ianux@free.fr>
+
+pkgname=woob-git
+pkgver=3.6.r333.gecb44eab4
+pkgrel=1
+pkgdesc="Core library and modules for Web Outside of Browsers"
+arch=(any)
+url="https://woob.tech"
+license=('LGPL3')
+depends=('python-lxml'
+         'python-cssselect'
+         'python-requests'
+         'python-dateutil'
+         'python-yaml'
+         'python-html2text'
+         'python-six'
+         'python-unidecode'
+         'python-pillow'
+         'python-babel'
+         'python-simplejson')
+optdepends=('python-prettytable: CLI output formatting'
+        'python-feedparser: required by some modules')
+makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools' 'git')
+replaces=('woob-headless' 'weboob')
+provides=('woob-headless')
+conflicts=('weboob-headless' 'weboob-git' 'weboob-qt')
+source=("woob::git+https://gitlab.com/woob/woob.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/woob"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${srcdir}/woob"
+  python -m build --wheel --no-isolation
+}
+
+package() {
+  cd "${srcdir}/woob"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+}
+